Jeremy Smith's blog: Binding to LDAP with Perl

Binding to LDAP with Perl

I plan on doing several of these "LDAP with Scripting Language X HowTos." This is the first one and, probably, the easiest one. I'll cover how to connect to LDAP with Perl over the basic connection, using TLS, and using SSL.

Basic Connecting to LDAP

#!/usr/bin/perl
use warnings;
use strict;

use Net::LDAP;
use Net::LDAP::LDIF;
use Net::LDAP::Util qw(ldap_error_text);

my $USERNAME = 'jms18';
my $PASSWORD = 'ImNotTelling';
my $LDAP_SERVER = 'ldap.cwru.edu';
my $LDAP_PORT = '389';
my $LDAP_BASE = 'ou=People,o=cwru.edu,o=isp';

my $userDN = "uid=$USERNAME,ou=People,o=cwru.edu,o=isp";

my $ldap = Net::LDAP->new($LDAP_SERVER, port => $LDAP_PORT)
			or die "Coult not create LDAP object because:\n$!";

my $ldapMsg = $ldap->bind($userDN, password => $PASSWORD);

die $ldapMsg->error if $ldapMsg->is_error;

my $ldapSearch = $ldap->search(base => $LDAP_BASE,
				filter => "uid=$USERNAME");


die "There was an error during search:\n\t" . ldap_error_text($ldapSearch->code) 
	if $ldapSearch->code;

print "No results returned\n" and exit 
	if( (!$ldapSearch) || ($ldapSearch->count == 0) );

my $ldif = Net::LDAP::LDIF->new(\*STDOUT, "a");
while(my $ldapEntry = $ldapSearch->pop_entry() )
{
	$ldif->write_entry($ldapEntry);
}

Connecting to LDAP Using TLS

#!/usr/bin/perl
use warnings;
use strict;

use Net::LDAP;
use Net::LDAP::LDIF;
use Net::LDAP::Util qw(ldap_error_text);
use Net::LDAP::Constant qw(LDAP_EXTENSION_START_TLS);

my $USERNAME = 'jms18';
my $PASSWORD = 'ImNotTelling';
my $LDAP_SERVER = 'ldap.cwru.edu';
my $LDAP_PORT = '389';
my $LDAP_BASE = 'ou=People,o=cwru.edu,o=isp';

my $userDN = "uid=$USERNAME,ou=People,o=cwru.edu,o=isp";

my $ldap = Net::LDAP->new($LDAP_SERVER, port => $LDAP_PORT)
			or die "Coult not create LDAP object because:\n$!";

my $dse = $ldap->root_dse();
my $doesSupportTLS = $dse->supported_extension(LDAP_EXTENSION_START_TLS);

die "Server does not support TLS\n" unless($doesSupportTLS);

my $startTLSMsg = $ldap->start_tls();

die $startTLSMsg->error if $startTLSMsg->is_error;

my $ldapMsg = $ldap->bind($userDN, password => $PASSWORD);

die $ldapMsg->error if $ldapMsg->is_error;

my $ldapSearch = $ldap->search(base => $LDAP_BASE,
			       filter => "uid=$USERNAME");


die "There was an error during search:\n\t" . ldap_error_text($ldapSearch->code) 
	if $ldapSearch->code;

print "No results returned\n" and exit 
	if( (!$ldapSearch) || ($ldapSearch->count == 0) );

my $ldif = Net::LDAP::LDIF->new(\*STDOUT, "a");
while(my $ldapEntry = $ldapSearch->pop_entry() )
{
	$ldif->write_entry($ldapEntry);
}

Connecting to LDAP Using SSL

#!/usr/bin/perl
use warnings;
use strict;

use Net::LDAPS;
use Net::LDAP::LDIF;
use Net::LDAP::Util qw(ldap_error_text);

my $USERNAME = 'jms18';
my $PASSWORD = 'ImNotTelling';
my $LDAP_SERVER = 'ldap.cwru.edu';
my $LDAP_SSL_PORT = '636';
my $LDAP_BASE = 'ou=People,o=cwru.edu,o=isp';

my $userDN = "uid=$USERNAME,ou=People,o=cwru.edu,o=isp";

my $ldap = Net::LDAPS->new($LDAP_SERVER, port => $LDAP_SSL_PORT)
			or die "Coult not create LDAP object because:\n$!";

my $ldapMsg = $ldap->bind($userDN, password => $PASSWORD);

die $ldapMsg->error if $ldapMsg->is_error;

my $ldapSearch = $ldap->search(base => $LDAP_BASE,
				filter => "uid=$USERNAME");


die "There was an error during search:\n\t" . ldap_error_text($ldapSearch->code) 
	if $ldapSearch->code;

print "No results returned\n" and exit 
	if( (!$ldapSearch) || ($ldapSearch->count == 0) );

my $ldif = Net::LDAP::LDIF->new(\*STDOUT, "a");
while(my $ldapEntry = $ldapSearch->pop_entry() )
{
	$ldif->write_entry($ldapEntry);
}

Comments

- Posted by: elshaa
- Posted on: January 23, 2007 04:55 PM
great examples ! quick, simple, efficient.
Thanks

Jeremy Smith's blog

Entry Is Labelled

Binding to LDAP with Perl

Basic Connecting to LDAP

Connecting to LDAP Using TLS

Connecting to LDAP Using SSL

Comments

Post a comment